-
Notifications
You must be signed in to change notification settings - Fork 21
/
create_experiment.pl
230 lines (189 loc) · 7.86 KB
/
create_experiment.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
#!/usr/bin/perl -w
#
# Copyright 2022, Google LLC
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.
#
# This example creates a new experiment, experiment arms, and demonstrates
# how to modify the draft campaign as well as begin the experiment.
use strict;
use warnings;
use utf8;
use FindBin qw($Bin);
use lib "$Bin/../../lib";
use Google::Ads::GoogleAds::Client;
use Google::Ads::GoogleAds::Utils::GoogleAdsHelper;
use Google::Ads::GoogleAds::Utils::FieldMasks;
use Google::Ads::GoogleAds::V16::Enums::ExperimentStatusEnum qw(SETUP);
use Google::Ads::GoogleAds::V16::Enums::ExperimentTypeEnum qw(SEARCH_CUSTOM);
use Google::Ads::GoogleAds::V16::Enums::ResponseContentTypeEnum
qw(MUTABLE_RESOURCE);
use Google::Ads::GoogleAds::V16::Resources::Campaign;
use Google::Ads::GoogleAds::V16::Resources::Experiment;
use Google::Ads::GoogleAds::V16::Resources::ExperimentArm;
use Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation;
use
Google::Ads::GoogleAds::V16::Services::ExperimentService::ExperimentOperation;
use
Google::Ads::GoogleAds::V16::Services::ExperimentArmService::ExperimentArmOperation;
use Google::Ads::GoogleAds::V16::Utils::ResourceNames;
use Getopt::Long qw(:config auto_help);
use Pod::Usage;
use Cwd qw(abs_path);
use Data::Uniqid qw(uniqid);
use POSIX qw(strftime);
sub create_experiment {
my ($api_client, $customer_id, $base_campaign_id) = @_;
my $experiment = create_experiment_resource($api_client, $customer_id);
my $draft_campaign =
create_experiment_arms($api_client, $customer_id, $base_campaign_id,
$experiment);
modify_draft_campaign($api_client, $customer_id, $draft_campaign);
# When you're done setting up the experiment and arms and modifying the draft
# campaign, this will begin the experiment.
my $response = $api_client->ExperimentService()->schedule_experiment({
# This is from the very first step above.
resourceName => $experiment
});
return 1;
}
# [START create_experiment_1]
sub create_experiment_resource {
my ($api_client, $customer_id) = @_;
my $experiment = Google::Ads::GoogleAds::V16::Resources::Experiment->new({
# Name must be unique.
name => "Example Experiment #" . uniqid(),
type => SEARCH_CUSTOM,
suffix => "[experiment]",
status => SETUP
});
my $operation =
Google::Ads::GoogleAds::V16::Services::ExperimentService::ExperimentOperation
->new({
create => $experiment
});
my $response = $api_client->ExperimentService()->mutate({
customerId => $customer_id,
operations => [$operation]});
my $resource_name = $response->{results}[0]{resourceName};
printf "Created experiment with resource name '%s'.\n", $resource_name;
return $resource_name;
}
# [END create_experiment_1]
# [START create_experiment_2]
sub create_experiment_arms {
my ($api_client, $customer_id, $base_campaign_id, $experiment) = @_;
my $operations = [];
push @$operations,
Google::Ads::GoogleAds::V16::Services::ExperimentArmService::ExperimentArmOperation
->new({
create => Google::Ads::GoogleAds::V16::Resources::ExperimentArm->new({
# The "control" arm references an already-existing campaign.
control => "true",
campaigns => [
Google::Ads::GoogleAds::V16::Utils::ResourceNames::campaign(
$customer_id, $base_campaign_id
)
],
experiment => $experiment,
name => "control arm",
trafficSplit => 40
})});
push @$operations,
Google::Ads::GoogleAds::V16::Services::ExperimentArmService::ExperimentArmOperation
->new({
create => Google::Ads::GoogleAds::V16::Resources::ExperimentArm->new({
# The non-"control" arm, also called a "treatment" arm, will automatically
# generate draft campaigns that you can modify before starting the
# experiment.
control => "false",
experiment => $experiment,
name => "experiment arm",
trafficSplit => 60
})});
my $response = $api_client->ExperimentArmService()->mutate({
customerId => $customer_id,
operations => $operations,
# We want to fetch the draft campaign IDs from the treatment arm, so the
# easiest way to do that is to have the response return the newly created
# entities.
responseContentType => MUTABLE_RESOURCE
});
# Results always return in the order that you specify them in the request.
# Since we created the treatment arm last, it will be the last result.
my $control_arm_result = $response->{results}[0];
my $treatment_arm_result = $response->{results}[1];
printf "Created control arm with resource name '%s'.\n",
$control_arm_result->{resourceName};
printf "Created treatment arm with resource name '%s'.\n",
$treatment_arm_result->{resourceName};
return $treatment_arm_result->{experimentArm}{inDesignCampaigns}[0];
}
# [END create_experiment_2]
sub modify_draft_campaign {
my ($api_client, $customer_id, $draft_campaign) = @_;
# In this block you can change anything you like about the campaign. These
# are the changes you're testing by doing this experiment. Here we just
# change the name for illustrative purposes, but generally you may want to
# change more meaningful parts of the campaign.
#
# You can also change underlying resources, such as ad groups and keywords,
# just as you would for any other campaign. When searching with the
# GoogleAdsService, be sure to include a PARAMETERS clause with
# `include_drafts = true` when searching for these draft entities.
my $updated_campaign = Google::Ads::GoogleAds::V16::Resources::Campaign->new({
resourceName => $draft_campaign,
name => "Modified Campaign Name " . strftime("%Y%m%d", localtime(time))});
my $operation =
Google::Ads::GoogleAds::V16::Services::CampaignService::CampaignOperation->
new({
update => $updated_campaign,
updateMask => all_set_fields_of($updated_campaign)});
my $response = $api_client->CampaignService()->mutate({
customerId => $customer_id,
operations => [$operation]});
printf "Updated the name for the campaign '%s'.\n", $draft_campaign;
return 1;
}
# Don't run the example if the file is being included.
if (abs_path($0) ne abs_path(__FILE__)) {
return 1;
}
# Get Google Ads Client, credentials will be read from ~/googleads.properties.
my $api_client = Google::Ads::GoogleAds::Client->new();
# By default examples are set to die on any server returned fault.
$api_client->set_die_on_faults(1);
my $customer_id;
my $base_campaign_id;
# Parameters passed on the command line will override any parameters set in code.
GetOptions(
"customer_id=s" => \$customer_id,
"base_campaign_id=i" => \$base_campaign_id
);
# Print the help message if the parameters are not initialized in the code nor
# in the command line.
pod2usage(2) if not check_params($customer_id, $base_campaign_id);
# Call the example.
create_experiment($api_client, $customer_id =~ s/-//gr, $base_campaign_id);
=pod
=head1 NAME
create_experiment
=head1 DESCRIPTION
This example creates a new experiment, experiment arms, and demonstrates how to modify the draft
campaign as well as begin the experiment.
=head1 SYNOPSIS
create_experiment.pl [options]
-help Show the help message.
-customer_id The Google Ads customer ID.
-base_campaign_id The base campaign ID.
=cut